%option noyywrap
%{
/* * * * * * * * * * * *
 * * * DEFINITIONS * * *
 * * * * * * * * * * * */

#include <string.h>
#include <string>
#include <list>
#include "graph.h"
#include "y.tab.h"

  extern int line_num;
%}

%x error
%x label

%%

%{
/* * * * * * * * * 
 * * * RULES * * *
 * * * * * * * * */
%}

[1-9][0-9]* {
  yylval.num = atoi(yytext);
  return NUMBER;
}

[ \t\f\r]	// ignore white space
\n              { line_num++; }

direction	{ return DIRECTION; }
vertical	{ return VERTICAL; }
horizontal      { return HORIZONTAL; } 
color { return COLOR; }
shape { return SHAPE; }
fontname { return FONTNAME; }
fontsize { return FONTSIZE; }
nodestyle { return NODESTYLE; }
edgestyle { return EDGESTYLE; }
"="  { return EQUALS;   }
","  { return COMMA;   }
";"  { return SEMI;   }
"["  { return LBRACK;   }
"]"  { return RBRACK;   }
"->"  { return ARROW;   }
\" { BEGIN(label); }
<label>[^\"\n] { yymore(); }
<label>\n { yymore(); line_num++; }
<label>\" {
  yytext[yyleng-1]='\0';
  yylval.lab = strdup(yytext);
  BEGIN(INITIAL); 
  return LABEL;
 }
[a-zA-Z][a-zA-Z0-9_]*	{ 
  yylval.name = strdup(yytext);  
  return NAME;
}

. { BEGIN(error); yymore(); }
<error>[^1-9=,;\[\]\-\"a-zA-Z \n\t\f\r] { yymore(); }
<error>. { yyless(yyleng-1); 
           printf("error token on line %d: %s\n", line_num, yytext); 
           BEGIN(INITIAL); }
<error>\n { yyless(yyleng-1); 
  printf("error token on line %d: %s\n", line_num, yytext); 
            line_num++;
            BEGIN(INITIAL); }