globals [
  half-width      ; half-width of axis row
  AG-half-width   ; half-width of anterior gradient row
  PG-half-width   ; half-width of posterior gradient row
  separation      ; separation between rows
  AG-offset       ; offset to row with anterior gradient
  PG-offset       ; offset to row with posterior gradient
  axis-row        ; the row on which the axis is displayed
  AG-row          ; the row on which the anterior gradient is displayed
  PG-row          ; the row on which the posterior gradient is displayed
  A_const         ; A gradient space constant
  P_const         ; P gradient space constant
  head-col        ; column position of head
  P-max           ; maximum P signal (decreases when growth limit reached)
  recording-movie?; set if recording a movie
  ]

breed [ tailbuds tailbud ]
breed [ heads head ]
breed [ somite-cells somite-cell ]

tailbuds-own [
  cycle           ; phase in clock cycle
  cell-cycle      ; phase in growth cycle
  ]
  
turtles-own [
  phase           ; phase of cell activity
  future-somite?  ; true if destined to become somite
  somite?         ; true if cell is in a somite
]

patches-own [
  activity        ; S activity (segmentation signal) of a cell
  A_signal        ; anterior signal
  A_new           ; new value of A (temp)
  P_signal        ; posterior signal
  P_new           ; new value of P (temp)
  occupied?       ; set if space occupied by somite-cell
  ]

to setup ; Initialize Simulation
  ;; (for this model to work with NetLogo's new plotting features,
  ;; __clear-all-and-reset-ticks should be replaced with clear-all at
  ;; the beginning of your setup procedure and reset-ticks at the end
  ;; of the procedure.)
  __clear-all-and-reset-ticks
  ; compute coordinates of display regions
  set half-width 8
  set AG-half-width 1
  set PG-half-width 1
  set separation 1
  set AG-offset 1 + half-width + separation + AG-half-width
  set PG-offset -1 - half-width - separation - PG-half-width
  set axis-row 0
  set AG-row axis-row + AG-offset
  set PG-row axis-row + PG-offset
  set head-col min-pxcor + 1
  
  ask patches [
    set activity 0
    set A_signal 0
    set P_signal 0
    set occupied? false
    set pcolor grey + 3                            ; light grey
  ]
  
  
  create-tailbuds 1 [ init-tailbud ]               ; one tailbud at right (posterior) end of embryo
  create-heads 1 [ init-head ]                     ; one head cell at left (anterior) end of embryo
  ask turtles [
    set phase 0
    set future-somite? false
    set somite? false
  ]
  ask heads [ set somite? true ]                   ; head acts like somite
  set P-max 100                                    ; tail bud emits this so long as growth continues
  set A_const sqrt (A_diff / (2 * A_decay))        ; space constant of A gradient
  set P_const sqrt (P_diff / (2 * P_decay))        ; space constant of P gradient
  display-axis                                     ; display initial state of embryo
  display-AG                                       ; display 0 A gradient
  display-PG                                       ; display 0 P gradient
  set recording-movie? false
end

to reset_defaults  ; Reset parameters to default values
  set growth_rate 2000
  set clock_period 500
  set A_diff 50
  set A_decay 10
  set P_diff 50
  set P_decay 5
  set A_upb 70
  set P_upb 10
  set S_lwb 95
  set initial_length 4
  set max_length max-pxcor
  set refractory_period 100
  set threshold 10
end

to init-tailbud
  set initial_length min list (max-pxcor - head-col - 1) initial_length ; ensure initial length in bounds
  setxy (head-col + initial_length) axis-row
  set shape "circle"
  set color blue
  set size 4
  set cycle 0
  set cell-cycle 0
  set heading 90
end

to init-head
  setxy head-col axis-row
  set shape "circle"
  set color green
  set size 4
end

to simulate ; Main simulation cycle
  diffuse-AG
  diffuse-PG
  ask tailbuds [ oscillate grow ] ; there is only one tailbud
  propagate-wave
  display-AG
  display-PG
  display-axis
  if recording-movie? and ticks mod frame-skip = 0 [movie-grab-view]
  tick
end

to oscillate ; Advance cycle of pacemaker with color changes
  set cycle cycle + 1
  ifelse cycle >= clock_period
  [ set cycle 0
    set color orange            ; orange indicates S has been emitted
    set activity 300 ]          ; 300 units of S emitted from tailbud
  [ if cycle > clock_period / 4 ; for visibility, tailbud stays orange for 1/4 cycle
    [ set color blue ]
  ]
end

to grow ; Tailbud grows (moves right) until limit reached
  ifelse xcor < (min list max_length max-pxcor) - 1 ; grow so long as less than limit
    [ fd growth_rate / 100000 ]                     ; grow at specified rate
    [ set P-max max list 0 (P-max - 1) ]            ; P-max decays when limit reached
  add-somite-cells                                  ; add somite-cells in unoccupied space
end

to add-somite-cells ; add somite-cells to left of tailbud
  ask patches with [ abs(pycor - axis-row) < half-width - 0.5 and pxcor >= head-col and pxcor < [xcor] of tailbud 0
                     and not occupied? ]
  [ if random 50 = 0 [sprout-somite-cells 1 [ init-somite-cell ] ] ]
end

to init-somite-cell
  set color white
  set shape "circle" 
  set size 1
  set somite? false
  set future-somite? false
  set activity 0
  set occupied? true
  setxy (xcor - 0.25 + random-float 0.5) (ycor - 0.25 + random-float 0.5)
end

to propagate-wave ; Implement propagation of S in excitable medium
  ; activity (S morphogen) at tailbud decays
  ask tailbuds [ set activity activity * 0.95 ]
  diffuse activity 0.75
  ; following addresses all patches on axis between head and tailbud (exclusive)
  ask somite-cells with [ abs(ycor - axis-row) <= half-width
        and xcor >= head-col and xcor < [xcor] of tailbud 0 ] [
    ; approximate diffusion and decay of S:
;    set activity activity
;     + (([activity / 4] of patch-at -1 0) + ([activity / 4] of patch-at 1 0)
;        + ([activity / 4] of patch-at 0 -1) + ([activity / 4] of patch-at 0 1) - activity)
;      * 0.75
    set activity activity * 0.95
    if phase >= 0 [                         ; REDUNDANT? (always >= 0)
      ifelse phase = 0                      ; refractory period is past
        [ if activity > threshold [         ; if threshold exceeded, cell fires
            set phase refractory_period     ; enter new refractory period
            set activity activity + 100 ] ] ; emit pulse of S
        [ set phase phase - 1               ; activity continues to decay during refractory period
          set activity max list 0 (activity - int (100 / refractory_period + 1) ) ] ]
    if not somite? and activity > S_lwb          ; four conditions for triggering somite formation
     and [ A_signal < A_upb ] of patch xcor axis-row
     and [ P_signal < P_upb ] of patch xcor axis-row
      [ set future-somite? true ]
    ]
  ; following addresses all patches involved in axis display
  ask somite-cells with [ abs(ycor - axis-row) <= half-width and xcor >= head-col and xcor < [pxcor] of tailbud 0 ] [
    if future-somite? ; if the cell on axis will be a new somite
    [ ; if cell to left is already a somite, then this is anterior boundary of new somite
      ifelse any? turtles-at -1 0 and [somite?] of one-of turtles-at -1 0
        [ set color yellow ] ; anterior compartment of somite
        [ set color brown ]  ; posterior compartment of somite
    ]
  ]
  ask somite-cells with [future-somite?] [ set future-somite? false set somite? true ] ; future somites commit
end

to diffuse-AG ; Diffuse anterior morphogen and set to maximum in somites
  ask patches with [ pycor = axis-row and pxcor > head-col and pxcor < [xcor] of tailbud 0 ]
  [ set A_new A_signal
     + (([A_signal / 2] of patch-at -1 0) + ([A_signal / 2] of patch-at 1 0) - A_signal) * A_diff / 100
    set A_new A_new * (1 - A_decay / 100) 
  ]
  ask patches with [ pycor = axis-row and pxcor > head-col and pxcor < [xcor] of tailbud 0 ]
   [ set A_signal A_new ]
;  diffuse A_signal (A_diff / 100)
  ask turtles with [somite?] [ ask patch-at 0 axis-row [set A_signal 100] ]
end

to diffuse-PG ; Diffuse posterior morphogen and set to P_max at tail bud.
  ask patch ([pxcor] of tailbud 0) axis-row [ set P_signal P-max ]
  ask patches with [ pycor = axis-row and pxcor > head-col and pxcor < [xcor] of tailbud 0 ]
  [ set P_new P_signal
     + (([P_signal / 2] of patch-at -1 0) + ([P_signal / 2] of patch-at 1 0) - P_signal) * P_diff / 100
    set P_new P_new * (1 - P_decay / 100) 
  ]
  ask patches with [ pycor = axis-row and pxcor > head-col and pxcor < [xcor] of tailbud 0 ]
  [ set P_signal P_new ]
end

to display-AG ; Display Anterior Gradient
  ; The lower bound is 1 because 0 seems to cause incorrect colors (black instead of white)
  ; for certain values near 0
  ask patches with [ abs(pycor - AG-row) <= AG-half-width and pxcor >= head-col and pxcor <= [xcor] of tailbud 0 ]
  [ set pcolor scale-color green ([A_signal] of patch pxcor axis-row) 150 1 ]
end

to display-PG ; Display Posterior Gradient
  ; The lower bound is 1 because 0 seems to cause incorrect colors (black instead of white)
  ; for certain values near 0
  ask patches with [ abs(pycor - PG-row) <= PG-half-width and pxcor >= head-col and pxcor <= [xcor] of tailbud 0 ]
  [ set pcolor scale-color blue ([P_signal] of patch pxcor axis-row) 150 1 ]
end

to display-axis ; Display segmentation (S) concentration of undifferentiated cells
;  ask patches with [ abs(pycor - axis-row) <= half-width and pxcor >= head-col and pxcor < [xcor] of tailbud 0 ]
;  [ if not [somite?] of patch pxcor axis-row
;     [ set pcolor scale-color orange ([activity] of patch pxcor axis-row) 0 150 ] ]
  ask somite-cells with [ abs(ycor - axis-row) <= half-width and xcor >= head-col and xcor < [xcor] of tailbud 0 ]
  [ if not somite?
     [ set color scale-color orange activity 0 150 ] ]
end
@#$#@#$#@
GRAPHICS-WINDOW
20
20
678
347
-1
18
8.0
1
10
1
1
1
0
0
0
1
0
80
-18
18
0
0
1
ticks
30.0

BUTTON
15
380
89
413
default
reset_defaults
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
120
380
186
413
setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
15
420
187
453
growth_rate
growth_rate
0
5000
2000
1
1
* 10^-5
HORIZONTAL

SLIDER
15
460
187
493
clock_period
clock_period
0
2000
500
1
1
NIL
HORIZONTAL

BUTTON
385
460
558
505
run
simulate
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
15
500
187
533
A_diff
A_diff
0
100
50
1
1
%
HORIZONTAL

SLIDER
15
540
187
573
A_decay
A_decay
0
100
10
1
1
%
HORIZONTAL

SLIDER
15
580
187
613
P_diff
P_diff
0
100
50
1
1
%
HORIZONTAL

SLIDER
15
620
187
653
P_decay
P_decay
0
100
5
1
1
%
HORIZONTAL

SLIDER
205
380
377
413
initial_length
initial_length
0
160
4
1
1
NIL
HORIZONTAL

SLIDER
205
580
378
613
refractory_period
refractory_period
0
1000
100
1
1
NIL
HORIZONTAL

SLIDER
205
620
377
653
threshold
threshold
0
100
10
1
1
NIL
HORIZONTAL

SLIDER
205
460
377
493
A_upb
A_upb
0
100
70
1
1
NIL
HORIZONTAL

SLIDER
205
500
377
533
P_upb
P_upb
0
100
10
1
1
NIL
HORIZONTAL

SLIDER
205
540
377
573
S_lwb
S_lwb
0
100
95
1
1
NIL
HORIZONTAL

MONITOR
385
380
467
425
A const
A_const
2
1
11

MONITOR
475
380
558
425
P const
P_const
2
1
11

SLIDER
205
420
377
453
max_length
max_length
0
160
160
1
1
NIL
HORIZONTAL

TEXTBOX
580
460
825
601
COLORS:\n\ngreen   - A morphogen\nblue     - P morphogen\norange - S morphogen\nyellow  - anterior boundary of somite\nbrown  - posterior part of somite
13
0.0
1

BUTTON
390
580
487
613
start movie
movie-start user-input \"Movie file name (with .mov)?\"\nset recording-movie? true
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
390
620
487
653
stop movie
set recording-movie? false\nmovie-close
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
390
540
562
573
frame-skip
frame-skip
1
50
1
1
1
NIL
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

Humans have 33 vertebrae, chickens have 55, mice have 65, and the corn snake has 315.  How does a developing embryo �count� the number of vertebrae it should produce, which is characteristic of its species?  This NetLogo model is based on the best contemporary explanation of this morphogenetic (form-producing) process, called the �clock and wavefront model� of embryological segmentation (Cooke & Zeeman, 1976; see References for recent work).

The vertebrae (and muscles and organs associated with them) develop from a series of somites that develop in order from the front (anterior) of the embryo to its tail (posterior).  In this process previously uncommitted cells differentiate into somite cells with definite boundaries between distinct somites.  The process is controlled by the concentrations of three different chemicals or �morphogens.�  The Anterior or A morphogen (probably retinoic acid in embryos) is produced by the cells that have already committed to be in somites, and it diffuses toward the tail of the embryo, forming a decreasing gradient from the somites to the tail.  The Posterior or P morphogen (e.g., FGF, Wnt) is produced by the embryo's tail bud, and it diffuses toward the head of the embryo, forming a decreasing gradient from the tail toward the head.  Where the P concentration falls below a certain threshold (called P_upb in this model) is called the �determination front,� since somites form in front of it.

Since the determination front is at a fixed distance in front of the tail bud, as the embryo grows the determination front moves rearward.  As a consequence there is an increasing gap between the determination front and the region of high A concentration near the most recently formed somites.  Since this region of low A and P concentrations is where the new somite will form, its size determines the size of the resulting somite, and therefore the embry's growth rate also has an effect on somite size.  (The large number of vertebrae in the corn snake results from a comparatively slow growth rate; see Gomez et al., 2008.)

The tail bud contains a biochemical �segmentation clock� that periodically produces a pulse of chemical that is a segmentation signal (Notch & HES proteins, called the �S morphogen� here); biologists are still elucidating the exact nature of this clock (Dequ�ant & Pourqui�, 2008).  The clock period is 1.5 hours in chickens, 1.7 hours in corn snakes, and 2 hours in mice, but 4-5 hours in humans.  The uncommitted cells form an �excitable medium,� which means that if the concentration of S around a cell is sufficiently high, the cell is stimulated to produce its own pulse of S.  As a consequence, when the clock cells produces a pulse of S, it causes a cascade of S production, which propagates in a wave from the tailbud toward the front of the embryo.  Since a cell enters an insensitive �refractory period� after it emits a pulse, the wave cannot go backward, but propagates in a single direction (another characteristic of excitable media).

When the S (segmentation) signal reaches cells in the region between the determination front and the previously formed somites (i.e., the region of low A and P concentrations), it triggers the cells in this region to commit to being somite cells.  Thus the amount of space that has opened between the A and P gradients (as determined by growth) between clock pulses defines the size of the new somite.  As the cells commit to becoming somite cells they use local chemical signals to decide whether they are at the anterior or posterior boundary of the somite (so, for example, they know whether to form the anterior or posterior end of a vertebra, thus establishing their polarity).

In real embryos, not all the somites are the same size, because the growth rate varies according to the developmental program of the species.

## HOW IT WORKS

After setup the model displays the initial state of the embryo in a band in the middle, the A gradient in the upper band, and the P gradient in the lower.  Furthermore, the central band has a green circle at the left end, representing the embryo's head, and a blue circle at the right end, representing the embryo's tail bud.

When the simulation is started, operation proceeds as follows.  On each time step the head circle set its A concentration to the maximum 100 and the tail bud sets its P concentration to the maximum (P-max, initially 100).  One-dimensional diffusion and decay of the A and P morphogens is simulated, and the resulting gradients are displayed.

The embryo grows to the right at the specified rate, and as it moves it sets the S morphogen of its patch to the maximum value (300) whenever its clock resets, which decays at a fixed rate.  The axis cells implement an excitable medium.  The S morphogen diffuses and decays at fixed rates, but if it exceeds a specified threshold in a cell that is not in its refractory period, then that cell will �fire� by adding 100 to its S concentration and enter its refractory period.  Due to the refractory property, the wave of S activity tends to propogate in one direction, from the tail bud toward the head.

In order for a patch to differentiate into a somite, both the A and P morphogens must be less than specified upper bounds (A_upb, P_upb), and the segmentation morphogen must be above a threshold (S_lwb).  Normally this occurs in a band to the right of the last differentiated somite, and so this is where the new somite forms.

When a patch differentiates into a somite it looks at the patch to its left (anterior side).  If it is already a somite, then the patch differentiates into an anterior boundary cell (yellow) of the new somite, otherwise it differentiates into a posterior compartment cell (brown).  Thus the yellow-brown segments are the somites.

When the embryo reaches its growth limit, the P-max value begins to decay toward 0, and so the P gradient eventually decays to 0.  Although the tail bud pacemaker continues to cycle, the segment structure is stable.

## HOW TO USE IT

DEFAULT sets the parameters to default values at which segmentation occurs.  They are a good place to begin investigation of the effects of the parameters.

SETUP initializes the simulation based on the specified parameters.  (Most parameters can be changed during a simulation run, however.)

RUN starts the simulation running.

Growth_Rate sets the number of fractions of a unit of length (one patch) that the embryo grows during each clock tick.

Clock_Rate defines the number of ticks between clock pulses from the tail bud.

A_diff, A_decay, P_diff, P_decay set the diffusion rate and decay rate for the anterior and posterior morphogens.  Each is defined as a percentage of the quantity at a patch that is distributed to adjacent patches (for diffusion) or eliminated (for decay).  To help in setting these parameters, monitors A_const and P_const display the length constant determined by the diff/decay ratio.  The length constant is the length, in patch units, over which the concentration decreases to 1/e = 37% of its maximum value.  (The diffusion rate determines how quickly the gradient is established.)

Initial_Length, Max_Length are the initial and maximum length (in patch units) of the embryo.  When it reaches the maximum length (or the right-hand boundary of the display), it stops growing.

A_upb, P_upb, S_lwb sets the morphogen thresholds at which cells will differentiate into somites.  The segmentation signal must be greater than S_lwb and the anterior and posterior gradients must be below A_upb and P_upb, respectively, in order for differentiation to occur.  This occurs in the region between the already differentiated somites and the determination boundary when a segmentation peak passes through.

Refractory Period is the period during which undifferentiated cells are insensitive to S (the segmentation morphogen) after they have emitted a pulse of S.  Thus the Refractory Period determines the maximum wave frequency.

Threshold is the minimum S (segmentation morphogen) level in adjacent cells in order for a cell to fire and emit its own pulse of S.

## THINGS TO NOTICE

[This section will some ideas of things for the user to notice while running the model.]

## THINGS TO TRY

[This section will give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.  This is all there is for now.]

With the clock_period set to 500, try different growth_rates from 500 to 5000 and oberve how it affects the size and number of segments.

Mutations can effect the stability of a morphogen and the concentrations of chemicals that break it down, thus altering the decay rate.  Other mutations can alter morphogens so as to affect their diffusion rates in embryonic tissue.  Keeping in mind that the space constant of the gradient is determined by the diff/decay ratio, experiment with the effects of different diffusion and decay rates on the pattern of segmentation.

To observe the wave propagation of the S (segmentation) signal, do the following.  Start with the Default parameters and set A_upb and P_upb to 0; this will prevent somite formation.  Set the growth_rate to 0 and the initial_length to something large, such as 100.  This will allow you to observe the wave propagating from the tail to the head of a relatively large, fixed-size embryo.  When you Run the simulation, watch the tail bud.  When it turns orange, it has generated a pulse of S.  The leading edge of the wave is orange, showing a high S concentration, while the trailing edge decays back to black.  Try a variety of different clock_periods longer than the refractory_period.  Then try setting the clock_period to less than the refractory_period.  Observe carefully what happens and try to explain it.

## EXTENDING THE MODEL

This section will give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.

## NETLOGO FEATURES

This model implements approximate one-dimensional diffusion directly, rather than using NetLogo's built-in diffusion commands, which are two-dimensional.

Agent sets (in particular patch sets) that vary with the growing embryo are used to address the patches in the various display regions and the patches involved in diffusion and wave front computations.

The scale-color operators have a lower bound of 1 (rather than 0), because a lower bound of 0 caused artifacts to appear in the gradient display.  It appears that certain values very near to 0 (and thus colors that should have been near white) were translated to black.

## CREDITS AND REFERENCES

For recent research on segmentation in embryological morphognesis, on which this model is based, see:

Dequ�ant, M.-L., & Pourqui�, O. (2008). Segmental patterning of the vertebrate embryonic axis. Nature Reviews Genetics 9: 370�82.

Gomez, C., �zbudak, E.M., Wunderlich, J., Baumann, D., Lewis, J., & Pourqui�, O. (2008). Control of segment number in vertebrate embryos. Nature 454: 335�9.

The original statement of the �clock and wavefront model� is:

Cooke, J., & Zeeman, E.C. (1976). A clock and wavefront model for control of the number of repeated structures during animal morphogenesis. J. Theor. Biol. 58: 455�76.

To refer to this model in academic publications, please use:  MacLennan, B.J. (2008).  NetLogo Segmentation model.  http://www.cs.utk.edu/~mclennan.  Dept. of Electrical Engineering & Computer Science, Univ. of Tennessee, Knoxville.

In other publications, please use:  Copyright 2008 Bruce MacLennan.  All rights reserved.  See http://www.cs.utk.edu/~mclennan/420/NetLogo4.0/Segmentation.html for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0beta2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@