globals [
  clock
  carrying-color
  free-color
]
turtles-own [
  carrying-food?
  drop-size     ;; how much chemical we're currently dropping
]
patches-own [
  chemical
  food
  nest?
  nest-scent
  food-source-number
  barrier?
]

to startup
  set free-color brown
  set carrying-color orange
end

;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to setup
  ca
  setup-turtles
  setup-patches
  set clock 0
  do-plotting
end

to setup-turtles
  set-default-shape turtles "bug"
  cct ants [
    set size 2  ;; easier to see this way
    rt random-float 360
;    set color free-color
    set color brown
    set carrying-food? false
  ]
end

to setup-patches
  ask patches [
    set chemical 0
    set food 0
    set food-source-number -1
    set barrier? false
    setup-nest
    setup-food
    update-display
  ]
  repeat 100 [diffuse nest-scent diffusion-rate / 100]
end

to setup-nest  ;; patch procedure
  ;; set nest? variable to true inside the nest
  ifelse (distancexy 0 0) < 5
  [ set nest? true
    set nest-scent 1000 ]
  [ set nest? false ]
end

to setup-food  ;; patch procedure
  ;; setup food source one on the right
  if ((distancexy (0.6 * max-pxcor) 0) < 5)
  [ set food-source-number 1 ]

  ;; setup food source two on the lower-left
  if ((distancexy (-0.6 * max-pxcor) (-0.6 * max-pycor)) < 5)
  [ set food-source-number 2 ]

  ;; setup food source three on the upper-left
  if ((distancexy (-0.8 * max-pxcor) (0.8 * max-pycor)) < 5)
  [ set food-source-number 3 ]

  ;; set "food" at sources to either 1 or 2
  if (food-source-number > 0)
  [ set food (1 + random 2) ]
end

to update-display  ;; patch procedure
  ;; give color to nest and food sources
  ifelse nest?
    [ set pcolor violet ] [
  ifelse barrier?
    [ set pcolor grey ] [
  ifelse (food > 0)
    [ if (food-source-number = 1) [ set pcolor cyan ]
      if (food-source-number = 2) [ set pcolor sky  ]
      if (food-source-number = 3) [ set pcolor blue ]
    ] [
  ifelse display-field = "chemical"
    [set pcolor scale-color green chemical 0.1 5 ] ;; scale color to show chemical concentration
;    [set pcolor scale-color red nest-scent 0 50 ] ;; scale color to show nest scent
    [set pcolor scale-color red (log (nest-scent + 0.1) 10) -1 3 ] ;; scale color to show nest scent
    ]]]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Runtime Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;

to go  ;; forever button
  ask turtles [ go-turtles ]
  diffuse chemical (diffusion-rate / 100)
  diffuse nest-scent (diffusion-rate / 100)
  ask patches [ go-patches ]
  do-plotting
  set clock (clock + 1)
end

to go-turtles  ;; turtle procedure
  if (who < clock) ;; delay the initial departure of ants
  [ ifelse carrying-food?
;    [set color carrying-color return-to-nest ]  ;; if ant finds food, it returns to the nest
;    [set color free-color     look-for-food  ]  ;; otherwise it keeps looking
    [set color orange return-to-nest ]  ;; if ant finds food, it returns to the nest
    [set color brown     look-for-food  ]  ;; otherwise it keeps looking
    avoid-barrier
  ]
end

to go-patches  ;; patch procedure
  set chemical (chemical * (100 - evaporation-rate) / 100)  ;;slowly evaporate chemical
  if barrier? [set chemical 0 set nest-scent 0]
  ifelse nest?
  [ set nest-scent 1000 ]
  [ set nest-scent nest-scent * 0.99 ]
  update-display  ;; Refresh the Display
end

to return-to-nest  ;; turtle procedure
  ifelse nest?  ;; if ant is in the nest, it drops food and heads out again
  [ set carrying-food? false
    rt 180 fd 1
  ]
  [ set chemical (chemical + drop-size) ;; drop some chemical, but the amount decreases each time
    set drop-size (drop-size - 1.5)
    if (drop-size < 1) [set drop-size 1]
    uphill-nest-scent   ;; head toward the greatest value of nest-scent
    wiggle              ;; which is toward the nest
    fd 1]
end

to look-for-food  ;; turtle procedure
  if (food > 0)
  [ set carrying-food? true  ;; pick up food
    set food (food - 1)      ;; and reduce the food source
    set drop-size 60
    rt 180 stop         ;; and turn around
  ]
  ifelse (chemical > 2)
  [ fd 1 ]
  [ ifelse (chemical < 0.05) ;; go in the direction where the chemical smell is strongest
    [ wiggle
      fd 1]
    [ uphill-chemical
      fd 1]
  ]
end

to uphill-chemical  ;; turtle procedure
  wiggle
  ;; sniff left and right, and go where the strongest smell is
  let scent-ahead chemical-of patch-ahead 1
  let scent-right chemical-scent 45
  let scent-left chemical-scent -45

  if ((scent-right > scent-ahead) or (scent-left > scent-ahead))
    [ ifelse (scent-right > scent-left)
      [ rt 45 ]
      [ lt 45 ]
  ]
end

to uphill-nest-scent  ;; turtle procedure
  wiggle

  ;; sniff left and right, and go where the strongest smell is
  let scent-ahead nest-scent-of patch-ahead 1
  let scent-right get-nest-scent 45
  let scent-left get-nest-scent -45

  if ((scent-right > scent-ahead) or (scent-left > scent-ahead))
  [ ifelse (scent-right > scent-left)
    [ rt 45 ]
    [ lt 45 ]
  ]
end

to wiggle  ;; turtle procedure
  rt random 40 - random 40
  if not can-move? 1
  [ rt 180 ]
end

to-report get-nest-scent [ angle ]
  let p patch-right-and-ahead angle 1
  if p != nobody
  [ report nest-scent-of p ]
  report 0
end

to-report chemical-scent [ angle ]
  let p patch-right-and-ahead angle 1
  if p != nobody
  [ report chemical-of p ]
  report 0
end

to avoid-barrier
  if (nobody != patch-ahead 1) and (barrier?-of patch-ahead 1)
    [right 90 + random 180]
  forward 1
end


to do-plotting
  if not plot? [ stop ]
  set-current-plot "Food of each kind"
  set-current-plot-pen "food-in-pile1"
  plot count patches with [pcolor = cyan]
  set-current-plot-pen "food-in-pile2"
  plot count patches with [pcolor = sky]
  set-current-plot-pen "food-in-pile3"
  plot count patches with [pcolor = blue]
end

to make-barrier
if mouse-down?
 [ask patches [
   if ((abs (pxcor - mouse-xcor)) < 2) and ((abs (pycor - mouse-ycor)) < 2)
   [set pcolor grey
    set barrier? true]]
 ]
end

to remove-barrier
if mouse-down?
 [ask patches [
   if ((abs (pxcor - mouse-xcor)) < 2) and ((abs (pycor - mouse-ycor)) < 2)
   [set pcolor black
    set barrier? false]
  update-display
  ]
 ]
end

to deposit-food
if mouse-down?
 [ask patches [
   if ((abs (pxcor - mouse-xcor)) < 2) and ((abs (pycor - mouse-ycor)) < 2)
   [ set food-source-number 1 + position food-kind ["cyan" "sky" "blue"]
     set food (1 + random 2) ]
  update-display
  ]
 ]
end

; *** NetLogo 3.1.4 Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING
; IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) --
; grant numbers REC #9814682 and REC-0126227.
; Converted from StarLogoT to NetLogo, 2001.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Ants model.
; http://ccl.northwestern.edu/netlogo/models/Ants.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/Ants
; for terms of use.
;
; *** End of NetLogo 3.1.4 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
257
10
764
538
35
35
7.0
1
10
1
1
1
0
0
0
1
-35
35
-35
35

CC-WINDOW
5
557
773
652
Command Center
0

BUTTON
5
37
73
70
NIL
setup
NIL
1
T
OBSERVER
T
NIL

SLIDER
31
121
210
154
diffusion-rate
diffusion-rate
0.0
99.0
50.0
1.0
1
NIL

SLIDER
31
162
210
195
evaporation-rate
evaporation-rate
0.0
99.0
10.0
1.0
1
NIL

BUTTON
78
37
148
70
NIL
go
T
1
T
OBSERVER
T
NIL

SWITCH
153
38
243
71
plot?
plot?
0
1
-1000

SLIDER
31
80
210
113
ants
ants
0
200
125
1
1
NIL

PLOT
6
347
249
543
Food of each kind
Time
Food
0.0
100.0
0.0
100.0
true
false
PENS
"food-in-pile1" 1.0 0 -11221820 true
"food-in-pile2" 1.0 0 -13791810 true
"food-in-pile3" 1.0 0 -13345367 true

CHOOSER
31
203
210
248
display-field
display-field
"chemical" "nest scent"
0

BUTTON
7
258
118
291
make barrier
make-barrier
T
1
T
OBSERVER
T
NIL

BUTTON
134
258
249
291
remove barrier
remove-barrier
T
1
T
OBSERVER
T
NIL

BUTTON
7
296
118
329
deposit food
deposit-food
T
1
T
OBSERVER
T
NIL

CHOOSER
134
296
249
341
food-kind
food-kind
"cyan" "sky" "blue"
0

@#$#@#$#@
WHAT IS IT?
-----------
In this project, a colony of ants forages for food. Each ant follows a set of simple rules, but the colony as a whole acts in a sophisticated way.

When an ant finds a piece of food, it carries the food back to the nest, dropping a chemical as it moves. When other ants "sniff" the chemical, they follow the chemical toward the food. As more ants carry food to the nest, they reinforce the chemical trail.


HOW TO USE IT
-------------
Click the SETUP button to set up the ant nest (in violet, at center) and three piles of food. Click the GO button to start the simulation. The chemical is shown in a green-to-white gradient, the nest-scent in a red-to-white gradient.

The EVAPORATION-RATE slider controls the evaporation rate of the chemical. The DIFFUSION-RATE slider controls the diffusion rate of the chemical and nest scent. There is an on-off PLOT? switch.  Turning off the plotting lets the model run faster.

The DISPLAY-FIELD chooser determines whether to display the chemical concentration or the nest-scent concentration.

The MAKE BARRIER button allows barriers to be drawn, which block the ants and diffusion of the chemical and nest scent. The REMOVE BARRIER allows some or all of the barriers to be erased. Click or hold the mouse button to draw or erase barriers.

The DEPOSIT FOOD button allows more food to be deposited.  The kind of food to be deposited ("cyan," "sky," or "blue") is determined by the FOOD-KIND chooser. Click or hold the mouse button to add food in particular places.


THINGS TO NOTICE
----------------
The ant colony generally exploits the food source in order, starting with the food closest to the nest, and finishing with the food most distant from the nest. It is more difficult for the ants to form a stable trail to the more distant food, since the chemical trail has more time to evaporate and diffuse before being reinforced.

Once the colony finishes collecting the closest food, the chemical trail to that food naturally disappears, freeing up ants to help collect the other food sources. The more distant food sources require a larger "critical number" of ants to form a stable trail.

The consumption of the food source is shown in a plot. In CYAN you see food1 which is on the right side of the world. In BLUE you see food2 which is on the lower left of the world.  In MAGENTA you see food3 which is on the upper left of the world.

Try creating a barrier between a food source and the nest.  How long does it take the ants to create a path around it?  If you make a hole through the barrier (with REMOVE BARRIER), how long does it take the ants to discover it?


EXTENDING THE MODEL
-------------------
Try different placements for the food sources. What happens if two food sources are equidistant from the nest? When that happens in the real world, ant colonies typically exploit one source then the other (not at the same time).

In this project, the ants use a "trick" to find their way back to the nest: they follow the "nest scent." Real ants use a variety of different approaches to find their way back to the nest. Try to implement some alternative strategies.


NETLOGO FEATURES
-------------------
In the UPHILL-CHEMICAL procedure, the ant "follows the gradient" of the chemical. That is, it "sniffs" in three directions, then turns in the direction where the chemical is strongest. You might want to try variants of the UPHILL-CHEMICAL procedure, changing the number and placement of "ant sniffs."

RETURN-TO-NEST uses a similar gradient.


CREDITS AND REFERENCES
-----------------------

Modified 2007-10-08 by B.J. MacLennan to simulate diffusion of nest-scent, to allow display of nest-scent, to allow insertion and removal of barriers, and to allow introduction of more food.

This model was developed at the MIT Media Lab.  See Resnick, M. (1994) "Turtles, Termites and Traffic Jams: Explorations in Massively Parallel Microworlds."  Cambridge, MA: MIT Press.  Adapted to StarLogoT, 1997, as part of the Connected Mathematics Project.  Adapted to NetLogo, 2001, as part of the Participatory Simulations Project.

To refer to this model in academic publications, please use:  Wilensky, U. (1998).  NetLogo Ants model.  http://ccl.northwestern.edu/netlogo/models/Ants.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use:  Copyright 1998 Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/Ants for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@