globals [
  architecture     ; list of number of neurons in each layer
  weight           ; list of weight matrices
  state            ; list of state vectors
  training-data    ; list of training pairs
  test-data        ; list of test pairs
  validation-data  ; list of validation pairs
  lwbX upbX        ; bounds on X values
  lwbY upbY        ; bounds on Y values
  lwbZ upbZ        ; bounds on Z values (if used)
  err-last-input   ; error on the last pattern processes
  training-error   ; average error over training data
  testing-error    ; average error over test data
  validation-error ; average error over validation data
  epoch            ; epoch number
  ]
  
to setup    ;;;; setup for an experiment ;;;;
  set-inputs
  set architecture fput inputs but-first architecture ; ensure correct number of inputs
  set epoch 0
  clear-outputs
end

to clear-outputs
  clear-all-plots
  clear-patches
  set err-last-input 0
  set training-error 0
  set testing-error 0
  set validation-error 0
end

to set-inputs ; set number of inputs and bounds appropriate for the problem
  ifelse Experiment = "Problem 1" [
      set inputs 2
      set lwbX -2 set upbX 2
      set lwbY -2 set upbY 2
    ]
  [ ifelse Experiment = "Problem 2" [
      set inputs 3
      set lwbX -2 set upbX 2
      set lwbY -2 set upbY 2
      set lwbZ -2 set upbY 2
      set plotting? false ; plotting not allowed on Problem 2
    ]
  [ ifelse Experiment = "Problem 3" [
      set inputs 2
      set lwbX -4 set upbX 10
      set lwbY -6 set upbY 6
    ]
  [ ifelse Experiment = "XOR" [
      set inputs 2
      set lwbX -2 set upbX 2
      set lwbY -2 set upbY 2
    ]
  [ ] ] ] ]
end

to enter-architecture
  let hidden-numbers read-from-string user-input
    "Enter neurons in each hidden layer, e.g., [4 3 6]"
  set-inputs
  set architecture fput inputs lput 1 hidden-numbers
  randomize-weights
end

to randomize-weights
  set weight (map [ random-weight-matrix ?1 ?2 ] ; matrix from ?1 neurons to ?2 neurons
    (but-last architecture) (but-first architecture))
  clear-outputs
end

to-report random-weight-matrix [m n] ; from m neurons (+ bias) to n neurons
  report n-values n [ n-values (m + 1) [ -0.1 + random-float 0.2 ] ]
end

to generate-data
  set training-data n-values training_samples [ random-pair ]
  set test-data n-values test_samples [ random-pair ]
  set validation-data n-values validation_samples [ random-pair ]
  wait 3
  clear-patches
end

to-report random-pair ; generate random input output pair for training, testing, or validation
  let ranX (random-input lwbX upbX)
  let ranY (random-input lwbY upbY)
  let pair []
  ifelse Experiment = "Problem 1"
    [ set pair list (list ranX ranY) Problem1 ranX ranY ]
  [ ifelse Experiment = "Problem 2"
    [ let ranZ (random-input lwbZ upbZ)
      set pair list (list ranX ranY ranZ) Problem2 ranX ranY ranZ
    ]
  [ ifelse Experiment = "Problem 3"
    [ set pair list (list ranX ranY) Problem3 ranX ranY ]
  [ ifelse Experiment = "XOR"
    [ set pair list (list ranX ranY) XOR-problem ranX ranY ]
  [ ] ] ] ]
  if plotting? [ plot-pair (first pair) (item 1 pair) ]
  report pair
end

to-report random-input [lwb upb] ; generate random number in specified bounds
  report lwb + random-float (upb - lwb)
end

to-report Problem1 [x y]
  report (1 + sin (90 * x) * cos (90 * y)) / 2
end

to-report Problem2 [x y z]
  report (x ^ 2 / 2 + y ^ 2 / 3 + z ^ 2 / 4) * 3 / 13
end

to-report Problem3 [x y] ; two overlapping Gaussians with 1/0 outputs
  let A_xy A-distribution x y
  let B_xy B-distribution x y
  report ifelse-value (A_xy >= random-float (A_xy + B_xy)) [1] [0]
end

to-report A-distribution [x y]
  report exp(-0.5 * (x * x + y * y)) / (2 * pi)
end

to-report B-distribution [x y]
  report exp(-0.125 * ((x - 2) ^ 2 + y * y)) / (8 * pi)
end

to-report XOR-problem [x y]
  report ifelse-value (x > 0 xor y > 0) [1] [0]
end

to train-one-epoch
  let total-training-error 0
  foreach shuffle training-data [ ; ? = an input-output pair
    set total-training-error total-training-error + error ?
    back-propagate ?
  ]
  set training-error total-training-error / length training-data
  set testing-error mean-error test-data
  set epoch epoch + 1
  set-current-plot-pen "training error"  plot training-error
  set-current-plot-pen "testing error"   plot testing-error
end

to validate
  set validation-error mean-error validation-data
end

to-report mean-error [data]
  report mean map [error ?] data
end

to-report error [sample-pair]
  let input first sample-pair
  let output forward-pass input
  set err-last-input difference output (last sample-pair)
  if plotting? [ plot-pair input output ]
  report err-last-input
end

to-report difference [output target] ;; squared error
  report (output - target) ^ 2
end

to-report forward-pass [input-vector]
  let prev-layer fput 1 input-vector ; prepend bias value
  set state (list prev-layer)        ; start list of state vectors (one per layer)
  foreach weight [                   ; ? = weight matrix between layers
    let local-fields mat-vec-prod ? prev-layer
    set prev-layer fput 1 map [sigmoid ?] local-fields ; prepend bias value
    set state lput prev-layer state
  ]
  report last last state ; there is only one output neuron
end

to-report sigmoid [x]
  report 1 / (1 + exp(- alpha * x)) ; alpha/4 = slope at x=0
end

to back-propagate [sample]
  let output last last state ; only one output neuron
  let target last sample
  let delta-output 2 * alpha * output * (1 - output) * (target - output)
  let deltas (list delta-output) ; begin list of vectors of delta values with output layer
  let Delta-output-weights outer-product deltas map [eta * ?] last butlast state
  let Delta-weights (list Delta-output-weights) ; begin list weight-change matrices
  ; the following could be more efficient (but less clear) by reversing the state and
  ; weight lists once each
  (foreach                            ; lists are reversed to backwards through the layers
    (reverse butlast butlast state)   ; ?1 = preceding state layer
    (reverse butlast weight)          ; ?2 = preceding weight layer
    (reverse butfirst butlast state)  ; ?3 = hidden state layer
    (reverse butfirst weight) [       ; ?4 = next weight layer
    set deltas compute-deltas ?3 ?4 deltas ; compute vector of delta values for this layer
    let Delta-hidden-weights outer-product deltas map [eta * ?] ?1 ; weight-change matrix
    set Delta-weights fput Delta-hidden-weights Delta-weights
  ])
  set weight
    (map [ (map [ (map [?1 + ?2] ?1 ?2) ] ?1 ?2) ] weight Delta-weights) ; sequence of matrix additions
end

to-report compute-deltas [states weights deltas] ; compute deltas for one layer
  ;; discard delta for bias neuron when computing deltas:
  report butfirst (map [ alpha * ?1 * (1 - ?1) * ?2 ] states (vec-mat-prod deltas weights))
end

to plot-pair [input output]
  let x round (max-pxcor * first input / upbX)
  let y floor (max-pycor * item 1 input / upbY)
  ask patch x y [
    set pcolor scale-color yellow output 0 1
  ]
end

;;; Vector and Matrix Operations ;;;

; Matrices are represented as a list of rows, each of which is a list (i.e., row-major order)

to-report inner-product [U V]
  report sum (map [?1 * ?2] U V)
end

to-report mat-vec-prod [M V] ; matrix-vector product
  report map [inner-product ? V] M
end

to-report vec-mat-prod [U M] ; vector-matrix product
  report map [ inner-product U column ? M ]
           n-values (length first M) [?]
end

to-report column [j M] ; report column-j of row-major matrix M
  report map [ item j ? ] M
end

to-report outer-product [U V]
  report map [scaler-product ? V] U
end

to-report scaler-product [x V] ; product of scalar and vector
  report map [x * ?] V
end
@#$#@#$#@
GRAPHICS-WINDOW
541
10
716
206
20
20
4.0244
1
10
1
1
1
0
0
0
1
-20
20
-20
20
0
0
1
ticks

SLIDER
15
10
185
43
inputs
inputs
1
5
2
1
1
units
HORIZONTAL

CHOOSER
15
45
185
90
Experiment
Experiment
"Problem 1" "Problem 2" "Problem 3" "XOR"
3

BUTTON
15
95
185
128
Enter Architecture
Enter-architecture
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
15
180
185
213
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
15
130
185
175
Architecture
architecture
0
1
11

SLIDER
15
250
187
283
training_samples
training_samples
0
2000
200
10
1
NIL
HORIZONTAL

SLIDER
15
285
187
318
test_samples
test_samples
0
200
100
10
1
NIL
HORIZONTAL

SLIDER
15
320
187
353
validation_samples
validation_samples
0
200
100
5
1
NIL
HORIZONTAL

BUTTON
15
355
185
388
Generate Data
generate-data
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
190
10
312
55
error on last input
err-last-input
3
1
11

MONITOR
190
60
310
105
training error
training-error
3
1
11

MONITOR
190
110
310
155
testing error
testing-error
3
1
11

MONITOR
190
160
310
205
validation error
validation-error
3
1
11

BUTTON
15
425
95
458
one epoch
train-one-epoch
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
107
425
187
458
train
train-one-epoch
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
65
465
142
498
NIL
validate
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
15
390
185
423
eta
eta
0
1
0.25
0.01
1
NIL
HORIZONTAL

PLOT
190
215
725
365
training
epoch
avg sq err
0.0
10.0
0.0
0.1
true
false
PENS
"training error" 1.0 0 -16777216 true
"testing error" 1.0 0 -2674135 true

BUTTON
15
215
185
248
randomize weights
randomize-weights
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
190
390
362
423
alpha
alpha
0
5
1
0.1
1
NIL
HORIZONTAL

SWITCH
430
10
537
43
plotting?
plotting?
0
1
-1000

TEXTBOX
411
374
561
402
training error - black\ntesting error  - red
11
0.0
1

@#$#@#$#@
WHAT IS IT?
-----------
This model demonstrates back-propagation neural-network learning on several problems.

In the future this section will give a general understanding of what the model is trying to show or explain.


HOW IT WORKS
------------
This section will explain what rules the agents use to create the overall behavior of the model.


HOW TO USE IT
-------------
This section will explain how to use the model, including a description of each of the items in the interface tab.

INPUTS - sets the number of inputs to the network.  This is forced to the correct value by selecting an EXPERIMENT.

EXPERIMENT - selects the experiment to perform.

ENTER ARCHITECTURE - allows you to enter a list of the number of neurons in each hidden layer.  For example, entering "[4 2]" puts 4 neurons in the first hidden layer and 2 in the second hidden layer.

ARCHITECTURE - displays the defined architecture, including the number of inputs (as defined by INPUTS) and the number of outputs (always 1 in this model).

SETUP - constructs a neural net with the defined architecture.  The interconnection weights are randomized.

RANDOMIZE WEIGHTS - randomizes the weights.  This is not necessary immediately after SETUP, but it can be used to retrain the net with different starting weights or learning parameters.

TRAINING SAMPLES - the number of sample input-output pairs used to train the neural net.

TEST SAMPLES - the number of samples used to test the net for generalization during training.  It is generally a good idea to stop training when the error on the test samples begins to increase.

VALIDATION SAMPLES - the number of samples used to test the net after training has been completed.

GENERATE DATA - generates the specified numbers of training, test, and validation sample input-output pairs.

ETA - the learning rate (0.2 is a good choice)

ALPHA - determines the slope of the sigmoid function at the origin, which is ALPHA/4.  ALPHA = 1 is a reasonable choice.

ONE EPOCH - trains the network for one epoch (one pass through all the training samples).

TRAIN - continuously trains, epoch after epoch, the neural net.

VALIDATE - tests the trained neural net on the validation data.  It is allowed to continue training after a validation test.

ERROR ON LAST INPUT - displays the squared error on last sample processed.

TRAINING ERROR - displays the average squared error over the training data on the last epoch.

TESTING ERROR - displays the average squared error over the testing data on the last epoch.

VALIDATION ERROR - displays the average squared error over the validation data from the last VALIDATE request.

GRAPH - displays the training error (black) and testing error (red) as a function of the epoch.

PLOTTING? - For Problems 1, 3, and XOR, displays the training, test, and validation data for a brief time after GENERATE DATA is pressed, displays the network outputs for the training and test samples during training, and displays the network outputs for the validation data when VALIDATE is requested.  This allows the learned behavior to be compared with the training data.  The samples are displayed as scaled patch colors. Plotting is automatically turned off for Problem 2, since the function is three-dimensional.


THINGS TO NOTICE
----------------
This section will give some ideas of things for the user to notice while running the model.


THINGS TO TRY
-------------
This section will give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.


EXTENDING THE MODEL
-------------------
This section will give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.


NETLOGO FEATURES
----------------
This section will point out any especially interesting or unusual features of NetLogo that the model makes use of, particularly in the Procedures tab.  It might also point out places where workarounds were needed because of missing features.


RELATED MODELS
--------------
This section will give the names of models in the NetLogo Models Library or elsewhere which are of related interest.


CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use:  MacLennan, B.J. (2008).  NetLogo Back-Propagation model.  http://www.cs.utk.edu/~mclennan.  Dept. of Electrical Engineering & Computer Science, Univ. of Tennessee, Knoxville.

In other publications, please use:  Copyright 2008 Bruce MacLennan.  All rights reserved.  See http://www.cs.utk.edu/~mclennan/420/NetLogo/Back-Propagation.html for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@