globals [ 
  changes 
  updates 
  time 
  showing_inhibitor?
  ]

patches-own [ activator
              inhibitor
              hold_activator
              hold_inhibitor
              new_pcolor
              old_pcolor ]

TO SETUP ;-----------------------------------------------------------------------------------------

;; (for this model to work with NetLogo's new plotting features,
  ;; __clear-all-and-reset-ticks should be replaced with clear-all at
  ;; the beginning of your setup procedure and reset-ticks at the end
  ;; of the procedure.)
  ;;__clear-all-and-reset-ticks                                                ; clears display, patches, and turtles

ca

set updates 0
set time 0

ask patches [
 ifelse random-float 100.0 < initial_density
 [set activator 100
  set inhibitor 100
  set pcolor white 
  set new_pcolor white]
 [set activator 0
  set inhibitor 0
  set pcolor black 
  set new_pcolor black]
]

reset-ticks

end


TO DRAW_WHITE ;--------------------------------------------------------------------------------------
if mouse-down?
 [ask patches
  [if ((abs (pxcor - mouse-xcor)) < 2) and ((abs (pycor - mouse-ycor)) < 2)
   [set pcolor white
    set activator 100                              ; creates live white cells where mouse button is depressed
    set inhibitor 100]]
 ]
end

TO DRAW_BLACK ;--------------------------------------------------------------------------------------
if mouse-down?
 [ask patches
  [if ((abs (pxcor - mouse-xcor)) < 2) and ((abs (pycor - mouse-ycor)) < 2)
   [set pcolor black
    set activator 0                                ; creates dead cells where mouse button is depressed
    set inhibitor 0]]
 ]
end


TO GO ;--------------------------------------------------------------------------------------------

set changes 0

ask-concurrent patches [
 repeat x_active                                  ; diffuses activator chemical in x direction
  [set activator ((activator + ([activator] of patch-at 1 0) + ([activator] of patch-at (-1) 0)) / 3)]
 repeat y_active                                  ; diffuses activator chemical in y direction
  [set activator ((activator + ([activator] of patch-at 0 1) + ([activator] of patch-at 0 (-1))) / 3)]

 repeat x_inhibit                                 ; diffuses inhibitor chemical in x direction
  [set inhibitor ((inhibitor + ([inhibitor] of patch-at 1 0) + ([inhibitor] of patch-at (-1) 0)) / 3)]
 repeat y_inhibit                                 ; diffuses inhibitor chemical in y direction
  [set inhibitor ((inhibitor + ([inhibitor] of patch-at 0 1) + ([inhibitor] of patch-at 0 (-1))) / 3)]

 set hold_activator activator
 set hold_inhibitor inhibitor
 set old_pcolor new_pcolor

 ifelse (bias + activator - inhibitor + (random (2 * noise)) - noise) > 0
  [set activator 100                               ;   turned on
   set inhibitor 100]
  [set activator 0                                 ;   turned off
   set inhibitor 0]
   
; set_color
 ifelse activator = 100
  [ set new_pcolor white ]
  [ set new_pcolor black ]  

  ifelse field_display = "none"
  [ set pcolor new_pcolor ]
  [ ifelse field_display = "activator"
    [ set pcolor scale-color red hold_activator 0 100 ]
    [ set pcolor scale-color blue hold_inhibitor 0 100 ]
  ]

 if new_pcolor != old_pcolor [ set changes changes + 1 ]
]

set updates changes
set time time + 1
plot updates

display

end

to set-random-seed
  random-seed read-from-string user-input "Random seed?"
end
@#$#@#$#@
GRAPHICS-WINDOW
324
21
738
456
50
50
4.0
1
10
1
1
1
0
1
1
1
-50
50
-50
50
0
0
1
ticks
30.0

BUTTON
21
20
89
53
set seed
set-random-seed
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
21
95
159
128
x_active
x_active
0
10
3
1
1
NIL
HORIZONTAL

SLIDER
162
95
304
128
x_inhibit
x_inhibit
0
30
5
1
1
NIL
HORIZONTAL

SLIDER
21
133
159
166
y_active
y_active
0
10
3
1
1
NIL
HORIZONTAL

SLIDER
162
133
304
166
y_inhibit
y_inhibit
0
30
5
1
1
NIL
HORIZONTAL

SLIDER
162
58
304
91
bias
bias
-10
10
0
1
1
NIL
HORIZONTAL

BUTTON
95
20
158
53
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
236
21
303
54
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
22
208
119
241
draw black
draw_black
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
13
296
111
341
simulation time
time
0
1
11

MONITOR
114
296
206
341
changed cells
updates
0
1
11

BUTTON
203
208
304
241
draw white
draw_white
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
54
450
154
495
% changed
updates * 100 / (world-width * world-height)
2
1
11

CHOOSER
90
247
228
292
field_display
field_display
"none" "activator" "inhibitor"
0

BUTTON
161
21
229
54
go once
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

PLOT
13
345
309
495
cells changed
NIL
NIL
0.0
10.0
0.0
100.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" ""

SLIDER
22
58
159
91
initial_density
initial_density
0
100
50
1
1
%
HORIZONTAL

SLIDER
92
170
231
203
noise
noise
0
100
0
1
1
NIL
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

Could it be that a single mechanism underlies such diverse patterns such as the stripes on a zebra, the spots on a leopard, and the blobs on a giraffe?  This model is a possible explanation of how the patterns on animals' skin self-organize.  If the model is right, then even though the animals may appear to have altogether different patterns, the rules underlying the formation of these patterns are the same and only some of the values (the numbers that the rules work on) are slightly different.

Thinking of the formation of fur in terms of rules also helps us understand how offspring of animals may have the same type of pattern, but not the same exact pattern. This is because what they have inherited is the rules and the values rather than a fixed picture. The process by which the rules and values generate a pattern is affected by chance factors, so each individual's pattern is different, but as long as the offspring receive the same rules and values, their own fur will self organize into the same type of pattern as their parents'.

## HOW IT WORKS

This program simulates vertebrate skin patterns by use of a short-range activator and a long-range inhibitor.  Each pigmented cell that is "turned on" (the white cells in the  
program) produces 100 units of an activating morphogen and 100 units of an inhibiting morphogen.  Both chemicals diffuse a specified number of times in the X and Y directions, and then each patch is evaluated.  Patches with more activator than inhibitor turn white, and patches with more inhibitor than activator turn black.  The process is then repeated; a steady-state pattern is usually quick to emerge.

## HOW TO USE IT

The SETUP button randomly colors each patch and deposits the morphogens on patches that are white.

The GO button executes the model according to the rules above.

The GO ONCE button executes a single cycle of the simulation, sp that the changes are easier to see.

The DRAW WHITE and DRAW BLACK buttons allow the user to use the mouse to draw white and black patches, respectively.

The X_ACTIVE, Y_ACTIVE, X_INHIBIT, and Y_INHIBIT sliders control the diffusion of the activator and inhibitor morphogens in each direction.  More specifically, the slider  
variables control the number of times that each patch shares its contents with its two neighbors (in the given direction), such that each patch is left with an equal share of the patch's original morphogens. 

INITIAL_DENSITY controls the initial density of activated cells (white patches).

The FIELD DISPLAY chooser controls the information displayed.  In its default position (NONE) is shows the color (white or black) of the cells.  If ACTIVATOR is chosen, then the concentration of the activator morphogen is displayed as a shade of red.  If INHIBITOR is chosen, then the concentration of the inhibitor morphogen is displayed as a shade of blue.  In either case the concentration is displayed after the morphogen has diffused, but before an activated cell secretes more of the morphogens.

## THINGS TO NOTICE

Modification of the absolute and relative sizes of the slider variables can cause a variety of patterns to emerge, resembling everything from zebras to vermiculated rabbit fish.

The display shows the number and percentage of cells (patches) that change color on each time step, and plots this as a function of time.  Notice how quickly the pattern stabilizes, but some of the cells (typically less than 1%) are always changing, showing that the pattern is not static but rather is a "stationary state."  You can see this by changing some of the parameters (diffusion rates and bias), which may destabilize the pattern and cause it to converge to a new stationary state. 

## THINGS TO TRY

Run the model with different INITIAL_DENSITY settings.  How, if at all, does the value of the INITIAL_DENSITY affect the emergent pattern?  Do you get the same pattern?  Do you get a different pattern?  Does it take longer?  Try very large and very small values (e.g., 99%, 1%).

Note how fragile the self organization of the cells is to slight changes in parameters. If you hold all other factors and slightly change just the BIAS	, from trial to trial, you will note that for large positive numbers you will invariably get completely white fur and for large negative numbers you will invariably get completely black fur (why is that?).  For values in between it fluctuates.  That happens partially because the initial setting of black/white coloration has a random element to it.

Try changing the sliders to have different values in the X and Y directions.

Once the pattern has stabilized, use the DRAW WHITE and DRAW BLACK controls to damage the pattern.  Then use GO or GO ONCE to see whether the pattern will heal and how quickly.  Does healing always restore the original pattern?

## EXTENDING THE MODEL

How about adding more colors? What could be the logic here? If you introduced, say, red, you would have to decide on specific conditions under which that color would appear. Also, you'd have to decide how that color influences other cells.

## RELATED MODELS

The Voting model, in the Social Science section of the NetLogo model library, is based on simpler rules but generates patterns that are similar in some respects.

## CREDITS AND REFERENCES

Modified by B. J. MacLennan Sep. 7, 2003 for Java StarLogo 2.0.2, Sep. 15, 2007 for NetLogo 3.2.4, and Sep. 12, 2008 for NetLogo 4.0.3 from original version by William Thies on Scott Camazine's website.  Modifications included monitoring of changed cells, field displays, and documentation.

Some of the above documentation is from the Fur model in the NetLogo model library (which is programmed differently, however): 

Wilensky, U. (2003).  NetLogo Fur model.  http://ccl.northwestern.edu/netlogo/models/Fur.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use:  Copyright 2003 Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/Fur for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0beta2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@